.include "m8def.inc"	; Используем ATMega8
			.include "define.asm"	; Наши все определения переменных тут
			.include "macro.asm"	; Все макросы у нас тут
			.include "vectors.asm"	; Все вектора прерываний спрятаны в этом файле
;=============================================================================			

			.ORG	INT_VECTORS_SIZE		
Reset:		OUTI 	SPL,low(RAMEND) 		
			OUTI	SPH,High(RAMEND)								
 
;=============================================================================
			.include "init.asm"			; Все инициализации тут.
;=============================================================================

			OUTI	OCR1BL,128
Main:		SEI							; Разрешаем прерывания.
			
			RCALL	Calc				; Вызваем замер напряжения.

			RJMP	Main
;=============================================================================
;Start Conversion
;=============================================================================
Calc:		OUTI	ACSR,(0<<ACBG)|(1<<ACIE)|(1<<ACIS1)|(1<<ACIS0) ; Запускаем компаратор, разрешаем прерывания, задаем тип срабатывания
			LDI		R21,255				; А этот наш регистр, определяющий уровень ШИМ
Calc_Loop:	OUT		OCR1AL,R21			; Выводим его в регистр сравнения Таймера

			RCALL	Delay				; Ждем пока сигнал установится (зависит от частоты ШИМ и фильтра)

			DEC		R21					; уменьшаем напряжение сравнения на 1
			BRNE	Calc_Loop			; Если не ноль - повторяем вновь.
			OUTI	ACSR,(0<<ACBG)|(0<<ACIE)|(1<<ACIS1)|(1<<ACIS0)		; выключаем компаратор, чтобы не шалил

			OUT		UDR,R20				; Вывод данных. Пока в УАПП, но потом можно куда угодно.
Exit_Calt:	RET							; Возврат
;=============================================================================			

Delay:		PUSH	R16
			PUSH	R17
			PUSH	R18
			PUSH	R19
			
			LDI		R16,1		
LD3:		LDI		R17,1
LD2:		LDI		R18,1
LD1:		LDI		R19,200
LD0:		NOP
			DEC		R19
			BRNE	LD0
			
			DEC		R18
			BRNE	LD1

			DEC		R17
			BRNE	LD2

			DEC		R16
			BRNE	LD3

			POP		R19
			POP		R18
			POP		R17
			POP		R16
			RET


;=============================================================================
; Interrupts
;=============================================================================
UART_RX:	RETI						; Выход из прерывания

;==============================================================================
UART_TX:	RETI

;==============================================================================
ADC_OK:		RETI

;=============================================================================
AIN_OK:		IN		R20,OCR1AL			; Как только сработало прерывание от компаратора выводим
			RETI						; значение из регистра сравнения в РОН и выходим.