AVR. Учебный курс. Операционная система. Установка

; Добавляем в него первым же делом инклюдник восьмой меги:
 
		.include "m8def.inc"	; Используем ATMega8
 
; Следом я добавляю файл с моими макроопределениями в котором записаны все символические имена 
; для ресурсов, вроде регистров, портов, отдельных пинов. ИМХО удобней все держать по разным 
; файлам, но тут уже дело за вашими привычками.
 
		.include "define.asm"
 
;Потом файл с макросами, он тоже отдельный и кочует из программы в программу. Именно там всякие 
; левые самодельные команды вроде OUTI прописаны. 
 
		.include "macro.asm"	; Все макросы у нас тут		
 
; Следом идет файл макросов ядра ОС. Он должен распологаться в начале программы, иначе компилятор 
; не поймет. Именно там прописаны макросы таймерной службы, добавления задачи и таймера, там же 
; заныкан стандартный макрос инциализации UART и многое другое. 
 
		.include "kernel_macro.asm"
 
;Дальше прописывается сегмент оперативной памяти в котором заранее определены 
; все очереди задач и таймеров. 
		.DSEG
		.equ 	TaskQueueSize = 11	; Размер очереди событий
TaskQueue: 	.byte 	TaskQueueSize 		; Адрес очереди сотытий в SRAM
		.equ 	TimersPoolSize = 5	; Количество таймеров
TimersPool:	.byte 	TimersPoolSize*3	; Адреса информации о таймерах
 
; Следом уже идет код, начинается кодовый сегмент. Надо заметить, что у меня вся таблица 
; Прерываний спрятана в vectors.asm и вместо таблицы в коде .include "vectors.asm" это удобно
 
		.CSEG
		.ORG 	0x0000		; Проц стартует с нуля, но дальше идут вектора 
		RJMP 	Reset	
 
		.ORG	INT0addr	; External Interrupt Request 0
		RETI
		.ORG	INT1addr	; External Interrupt Request 1
		RETI
 
	.ORG	OC2addr			; Timer/Counter2 Compare Match
	RJMP	OutComp2Int		;<<<<<<<< Прерывание ОС!!!
 
		.ORG	OVF2addr	; Timer/Counter2 Overflow
		RETI
		.ORG	ICP1addr	; Timer/Counter1 Capture Event
		RETI
		.ORG	OC1Aaddr	; Timer/Counter1 Compare Match A
		RETI
		.ORG	OC1Baddr	; Timer/Counter1 Compare Match B
		RETI
		.ORG	OVF1addr	; Timer/Counter1 Overflow
		RETI
		.ORG	OVF0addr	; Timer/Counter0 Overflow
		RETI
		.ORG	SPIaddr		; Serial Transfer Complete
		RETI
		.ORG	URXCaddr	; USART, Rx Complete
		RJMP	Uart_RCV
		.ORG	UDREaddr	; USART Data Register Empty
		RETI
		.ORG	UTXCaddr	; USART, Tx Complete
		RJMP	Uart_TMT
		.ORG	ADCCaddr	; ADC Conversion Complete
		RETI
		.ORG	ERDYaddr	; EEPROM Ready
		RETI
		.ORG	ACIaddr		; Analog Comparator
		RETI
		.ORG	TWIaddr		; 2-wire Serial Interface
		RETI
		.ORG	SPMRaddr	; Store Program Memory Ready
		RETI
		.ORG	INT_VECTORS_SIZE	; Конец таблицы прерываний

; Interrupts procs
; Output Compare 2 interrupt  - прерывание по совпадению TCNT2 и OCR2
; Main Timer Service - Служба Таймеров Ядра - Обработчик прерывания
 
OutComp2Int:	TimerService	; Служба таймера OS 
				; Весь код обработчика в виде одного макроса
				; Просто вставил и все. Куда угодно. Можно извратиться
				; Подать импульсы с нужной частотой на какой-нибудь
				; INT0 и службу таймеров повесить на его прерывание
				; Разумеется, в таблице векторов из вектора  прописан 
				;переход сюда	
		RETI		; выходим из прерывания
 
Uart_RCV:	RETI		; Другие прерывания если нужны
Uart_TMT:	RETI

Reset:		OUTI 	SPL,low(RAMEND) 		; Первым делом инициализируем стек
		OUTI	SPH,High(RAMEND)

; init.asm 
; Очистка памяти
RAM_Flush:	LDI	ZL,Low(SRAM_START)
		LDI	ZH,High(SRAM_START)
		CLR	R16
Flush:		ST 	Z+,R16
		CPI	ZH,High(RAMEND)
		BRNE	Flush
 
		CPI	ZL,Low(RAMEND)
		BRNE	Flush
 
		CLR	ZL
		CLR	ZH
 
; Init RTOS			; В исходнике все сделано 
;		INIT_RTOS	; вот так вот, одним макросом. Макрос описан 
;				; в файле kernel_macro.asm
;				; Но я распишу тут подробно. Там идет настройка
;				; Таймера в работу
 
; Содержимое макроса INIT_RTOS
 
		OUTI 	SREG, 0		; Сброс всех флагов 
 
		rcall ClearTimers	; Очистить список таймеров РТОС
		rcall ClearTaskQueue	; Очистить очередь событий РТОС
		sei			; Разрешить обработку прерываний
 
; Настройка таймера 2 - Основной таймер для ядра
 
		.equ 	MainClock 	= 8000000		; CPU Clock
		.equ 	TimerDivider 	= MainClock/64/1000 	; 1 mS
 
		OUTI 	TCCR2,1<<CTC2|4<<CS20	; Установить режим CTC и предделитель =64
		OUTI 	TCNT2,0			; Установить начальное значение счётчиков
 
 
		ldi OSRG,low(TimerDivider)
		out OCR2,OSRG			; Установить значение в регистр сравнения
; Конец макроса INIT_RTOS
 
 
		OUTI	TIMSK,1<<OCF2 		; Разрешить прерывание по сравнению
 
; Инициализация остальной периферии
		USART_INIT
; Конец init.asm

Background:	NOP 		; Пока тут ничего нет

Main:	SEI				; Разрешаем прерывания.
	wdr				; Reset Watch DOG 
	rcall 	ProcessTaskQueue	; Обработка очереди процессов
	rcall 	Idle			; Простой Ядра
	rjmp 	Main			; Основной цикл микроядра РТОС
 
; В Idle можно сунуть что нибудь простое, быстрое и некритичное.
; Но я обычно оставляю его пустым.

Idle:		RET
;-----------------------------------------------------------------------------
Task1:		RET
;-----------------------------------------------------------------------------
Task2:		RET
;-----------------------------------------------------------------------------
Task3:		RET
;-----------------------------------------------------------------------------
Task4:		RET
;-----------------------------------------------------------------------------
Task5:		RET
;-----------------------------------------------------------------------------
Task6:		RET
;-----------------------------------------------------------------------------
Task7:		RET
;-----------------------------------------------------------------------------
Task8:		RET
;-----------------------------------------------------------------------------
Task9:		RET
 
; А после секции задач вставляем шаблонную таблицу переходов и код ядра
		.include "kerneldef.asm"	; Подключаем настройки ядра
		.include "kernel.asm"		; Подклчюаем ядро ОС
 
TaskProcs: 	.dw Idle		; [00] 
		.dw Task1		; [01] 
		.dw Task2		; [02] 
		.dw Task3		; [03] 
		.dw Task4 		; [04] 
		.dw Task5		; [05] 
		.dw Task6		; [06] 
		.dw Task7		; [07] 
		.dw Task8		; [08]
		.dw Task9		; [09]